哆啦A梦

<?php
$cityname="福州";
$gethtml=@file_get_contents("http://weather.cn.yahoo.com/weather.html?city=".urlencode(mb_convert_encoding($cityname, 'UTF-8','GB2312'))."");
preg_match_all("/<span class=\"f14\"><strong>.+<\/span>/",$gethtml,$matches);
print_r($matches);
?>

<%
dim Jmail,sendstate '定义变量

set Jmail=Server.CreateObject("JMail.Message") '建立一个JMail对象

Jmail.logging=true '启用日志功能，启用后可以使用Jmail.log返回W3 JMail创建的日志等

Jmail.silent=true
'设置为True后，使用Send方法将忽略所有错误而不将错误返回给操作系统，Send方法并返回一个布尔变量，发送成功返回True，反之返回Flase
'设置为True后，如果发送失败，可以使用Jmail.ErrorCode返回错误号或Jmail.ErrorMessage返回错误说明，以便知道发生什么错误

Jmail.Charset="gb2312" '设置邮件使用的字符，不设置默认为US-ASCII

Jmail.Priority=3 '设置邮件的优先级，设置3表示中等

Jmail.from="发件人的邮箱地址" '邮箱格式，收信人点回复的邮箱地址默认就是这个

Jmail.fromname="发件人的姓名" '不是很重要，可以不设置

Jmail.AddRecipient "收件人邮箱地址","收件人姓名"
'一般常见使用2个参数，当然没有姓名你可以去掉第2个姓名参数
'想发送给多个邮箱，可以多写几行此方法，分别设置不一样的邮箱

Jmail.mailserverusername="SMTP服务器登录用户名" 'Smtp认证时需要的登录用户名，门户申请的邮箱一般不带@及后面的域名

Jmail.mailserverpassword="SMTP服务器登录密码" '这个不用多说了吧

Jmail.subject="邮件的标题"

'这样添加一个普通邮件附件，可选
Jmail.AddAttachment(Server.MapPath("附件的相对路径"))

'这样添加一个内嵌邮件附件，可选
dim attachmentid '定义一个附件的变量
attachmentid=Jmail.AddAttachment(Server.MapPath("附件的相对路径")) '插入附件使用"cid:" & contentId。比如MailBody="<img src=""cid:" & contentId & """>"

'邮件内容设置开始
'如果你想使用HTML格式发送：
Jmail.ContentType = "text/html" '设置邮件正文格式为html
Jmail.htmlbody="邮件的具体内容" '就是html的格式内容

'如果你想使用文本格式发送：
Jmail.body="邮件的具体内容" '这里就是文本内容asp可以使用vbcrlf或vbnewline文本换行
'以上2种格式发送看自己需求选择一种
'邮件内容设置结束

if not Jmail.send("邮件的SMTP服务器") then
'上面的登录用户名和密码必须和这边的对应。门户邮箱一般为（smtp.域名.域名后缀），企业邮局常见为（mail.域名.域名后缀）
sendstate=false
else
sendstate=true
end if

Jmail.close '关闭对象
set Jmail=nothing '清空对象

'下面还可以利用sendstate变量来判断邮件发送与否的处理，当然你如果有能力可以写成函数更好。
%>